map(Ring,Ring,Matrix) -- make a ring map

Synopsis

Usage:
map(R,S,m)
Function: map
Inputs:
- R, a ring, the target ring
- S, a ring, the source ring
- m, a matrix, a 1 by n matrix over R, where n is the number of variables in the polynomial ring S, or a matrix over the common coefficient ring of the two rings.
Outputs:
- a ring map, the ring homomorphism from S to R which, in case m is a matrix over R, sends the i-th variable of S to the i-th entry in m, or, in case m is a matrix over the common coefficient ring, is the linear change of coordinates corresponding to m
Optional inputs:
- Degree => ..., -- set the degree of a map
- DegreeMap => ...,

Description

i1 : R = ZZ[x,y];

i2 : S = ZZ[a,b,c];

i3 : f = map(R,S,matrix {{x^2,x*y,y^2}})

               2        2
o3 = map(R,S,{x , x*y, y })

o3 : RingMap R <--- S

i4 : f(a+b+c^2)

      4    2
o4 = y  + x  + x*y

o4 : R

i5 : g = map(R,S,matrix {{1,2,3},{4,5,6}})

o5 = map(R,S,{x + 4y, 2x + 5y, 3x + 6y})

o5 : RingMap R <--- S

i6 : g(a+b)

o6 = 3x + 9y

o6 : R

If the coefficient ring of S is itself a polynomial ring, then one may optionally include values to which its variables should be sent: they should appear last in the matrix m.

i7 : S = ZZ[a][b,c];

i8 : h = map(S,S,matrix {{b,c,2*a}})

o8 = map(S,S,{b, c, 2a})

o8 : RingMap S <--- S

i9 : h(a^7 + b^3 + c)

      3           7
o9 = b  + c + 128a

o9 : S

i10 : k = map(S,S,matrix {{c,b}})

o10 = map(S,S,{c, b, a})

o10 : RingMap S <--- S

i11 : k(a^7 + b^3 + c)

       3        7
o11 = c  + b + a

o11 : S

map(Ring,Ring,Matrix) -- make a ring map

Synopsis

Description

See also